readline: update to version 6.1

from 5.2
version 5.2 is still kept since it's the latest version
under GPLv2+.

changes:
  - change autotools_do_configure and use do_configure_prepend
  - similar to do_install_append

Signed-off-by: Qing He <qing.he@intel.com>

diff --git a/meta/packages/readline/readline-5.2/acinclude.m4 b/meta/packages/readline/files/acinclude.m4
similarity index 100%
rename from meta/packages/readline/readline-5.2/acinclude.m4
rename to meta/packages/readline/files/acinclude.m4

diff --git a/meta/packages/readline/readline-5.2/configure_fix.patch b/meta/packages/readline/files/configure-fix.patch
similarity index 100%
rename from meta/packages/readline/readline-5.2/configure_fix.patch
rename to meta/packages/readline/files/configure-fix.patch

diff --git a/meta/packages/readline/readline.inc b/meta/packages/readline/readline.inc
new file mode 100644 (file)
index 0000000..f8bb45a
--- /dev/null
+++ b/meta/packages/readline/readline.inc
@@ -0,0 +1,35 @@
+DESCRIPTION = "The GNU Readline library provides a set of functions for use by applications that allow users to edit \
+command lines as they are typed in. Both Emacs and vi editing modes are available. The Readline library includes  \
+additional functions to maintain a list of previously-entered command lines, to recall and perhaps reedit those   \
+lines, and perform csh-like history expansion on previous commands."
+SECTION = "libs"
+PRIORITY = "optional"
+
+# GPLv2+ (< 6.0), GPLv3+ (>= 6.0)
+LICENSE = "GPLv3+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+
+DEPENDS += "ncurses"
+RPROVIDES_${PN} += "readline"
+
+SRC_URI = "${GNU_MIRROR}/readline/${BPN}-${PV}.tar.gz \
+           file://configure-fix.patch \
+           file://acinclude.m4"
+
+S = "${WORKDIR}/${BPN}-${PV}"
+
+inherit autotools
+
+LEAD_SONAME = "libreadline.so"
+
+do_configure_prepend () {
+       install -m 0644 ${WORKDIR}/acinclude.m4 ${S}/
+}
+
+do_install_append () {
+       # Make install doesn't properly install these
+       oe_libinstall -so -C shlib libhistory ${D}${libdir}
+       oe_libinstall -so -C shlib libreadline ${D}${libdir}
+}
+
+BBCLASSEXTEND = "native"

diff --git a/meta/packages/readline/readline_5.2.bb b/meta/packages/readline/readline_5.2.bb
index 10ce18fe9a311441a00b6df73afdbb0ccf0a381c..10f88ce19629b06eaf06c63a2e78ecdc93a51156 100644 (file)
--- a/meta/packages/readline/readline_5.2.bb
+++ b/meta/packages/readline/readline_5.2.bb
@@ -1,33 +1,5 @@
-DESCRIPTION = "The GNU Readline library provides a set of functions for use by applications that allow users to edit \
-command lines as they are typed in. Both Emacs and vi editing modes are available. The Readline library includes  \
-additional functions to maintain a list of previously-entered command lines, to recall and perhaps reedit those   \
-lines, and perform csh-like history expansion on previous commands."
-SECTION = "libs"
-PRIORITY = "optional"
-LICENSE = "GPLv2"
-DEPENDS += "ncurses"
-RPROVIDES_${PN} += "readline"
-LEAD_SONAME = "libreadline.so"
-PR = "r4"
+require readline.inc
 
-SRC_URI = "ftp://ftp.gnu.org/gnu/readline/readline-${PV}.tar.gz \
-           file://configure_fix.patch;patch=1 \
-           file://acinclude.m4"
-
-S = "${WORKDIR}/readline-${PV}"
-
-inherit autotools
-
-do_configure () {
-       install -m 0644 ${WORKDIR}/acinclude.m4 ${S}/
-       autotools_do_configure
-}
-
-do_install () {
-       autotools_do_install
-       # Make install doesn't properly install these
-       oe_libinstall -so -C shlib libhistory ${D}${libdir}
-       oe_libinstall -so -C shlib libreadline ${D}${libdir}
-}
-
-BBCLASSEXTEND = "native"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=03b36fdd84f74b8d8189a202b980b67f"
+PR = "r5"

diff --git a/meta/packages/readline/readline_6.1.bb b/meta/packages/readline/readline_6.1.bb
new file mode 100644 (file)
index 0000000..c327556
--- /dev/null
+++ b/meta/packages/readline/readline_6.1.bb
@@ -0,0 +1,3 @@
+require readline.inc
+
+PR = "r0"