mesa: Update to follow OE-Core changes

This updates the bbappend to the newer version; as mesa now provides
the needed PACKAGECONFIG settings we rely on this instead of using an
annonymous Python code to change it during build time.

The bbappend file now is much easier to read.

Change-Id: Ie7b6027462f458d139d0561e737b254dd8b07653
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
Tested-by: Gary Thomas <gary@mlbassoc.com>
Tested-by: John Weber <rjohnweber@gmail.com>

diff --git a/meta-fsl-arm/recipes-graphics/mesa/mesa_%.bbappend b/meta-fsl-arm/recipes-graphics/mesa/mesa_%.bbappend
new file mode 100644 (file)
index 0000000..8e0a36b
--- /dev/null
+++ b/meta-fsl-arm/recipes-graphics/mesa/mesa_%.bbappend
@@ -0,0 +1,10 @@
+PACKAGECONFIG_remove_mx5 = "egl gles"
+PROVIDES_remove_mx5 = "virtual/libgles1 virtual/libgles2 virtual/egl"
+
+PACKAGECONFIG_remove_mx6 = "egl gles"
+PROVIDES_remove_mx6 = "virtual/libgl virtual/libgles1 virtual/libgles2 virtual/egl"
+
+# FIXME: Dirty hack to allow use of Vivante GPU libGL binary
+do_install_append_mx6 () {
+    rm -f ${D}${libdir}/libGL.*
+}

diff --git a/meta-fsl-arm/recipes-graphics/mesa/mesa_9.2.2.bbappend b/meta-fsl-arm/recipes-graphics/mesa/mesa_9.2.2.bbappend
deleted file mode 100644 (file)
index 9975abc..0000000
--- a/meta-fsl-arm/recipes-graphics/mesa/mesa_9.2.2.bbappend
+++ /dev/null
@@ -1,40 +0,0 @@
-# FIXME: We may need to disable EGL, GL ES1 and GL ES2
-python __anonymous () {
-    import re
-
-    # SoC families to work on
-    families = ['mx5', 'mx6']
-    cur_soc_families = d.getVar('SOC_FAMILY', True)
-    if cur_soc_families and \
-        any(map(lambda x: x in cur_soc_families.split(':'), families)):
-        # Remove egl gles1 and gles2 configure options
-        extra_oeconf = d.getVar('EXTRA_OECONF', True).split()
-        take_out = ['--enable-egl', '--enable-gles1', '--enable-gles2']
-        put_in = ['--disable-egl', '--disable-gles1', '--disable-gles2']
-        pattern = re.compile("--with-egl-platforms")
-        new_extra_oeconf = []
-        for i in extra_oeconf:
-            if i not in take_out and not pattern.match(i):
-                new_extra_oeconf.append(i)
-        for i in put_in:
-            new_extra_oeconf.append(i)
-
-        d.setVar('EXTRA_OECONF', ' '.join(new_extra_oeconf))
-
-        # Remove itens from provides
-        provides = d.getVar('PROVIDES', True).split()
-        take_out = ['virtual/libgles1', 'virtual/libgles2', 'virtual/egl']
-        if 'mx6' in cur_soc_families.split(':'):
-            take_out.append('virtual/libgl')
-        new_provides = []
-        for i in provides:
-            if i not in take_out:
-                new_provides.append(i)
-
-        d.setVar('PROVIDES', ' '.join(new_provides))
-}
-
-# FIXME: Dirty hack to allow use of Vivante GPU libGL binary
-do_install_append_mx6 () {
-    rm -f ${D}${libdir}/libGL.*
-}