linux-libc-headers: add 2.6.39

The 2.6.37.2 version is kept to allow the qemu kernels and libc headers version to match

diff --git a/meta/recipes-kernel/linux-libc-headers/linux-libc-headers_2.6.39.bb b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers_2.6.39.bb
new file mode 100644 (file)
index 0000000..65c19ec
--- /dev/null
+++ b/meta/recipes-kernel/linux-libc-headers/linux-libc-headers_2.6.39.bb
@@ -0,0 +1,49 @@
+require linux-libc-headers.inc
+
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS += "unifdef-native"
+
+SRC_URI += " file://connector-msg-size-fix.patch"
+SRC_URI[md5sum] = "1aab7a741abe08d42e8eccf20de61e05"
+SRC_URI[sha256sum] = "584d17f2a3ee18a9501d7ff36907639e538cfdba4529978b8550c461d45c61f6"
+
+S = "${WORKDIR}/linux-${PV}"
+
+set_arch() {
+       case ${TARGET_ARCH} in
+               alpha*)   ARCH=alpha ;;
+               arm*)     ARCH=arm ;;
+               cris*)    ARCH=cris ;;
+               hppa*)    ARCH=parisc ;;
+               i*86*)    ARCH=i386 ;;
+               ia64*)    ARCH=ia64 ;;
+               mips*)    ARCH=mips ;;
+               m68k*)    ARCH=m68k ;;
+               powerpc*) ARCH=powerpc ;;
+               s390*)    ARCH=s390 ;;
+               sh*)      ARCH=sh ;;
+               sparc64*) ARCH=sparc64 ;;
+               sparc*)   ARCH=sparc ;;
+               x86_64*)  ARCH=x86_64 ;;
+               avr32*)   ARCH=avr32 ;;
+               bfin*)    ARCH=blackfin ;;
+               microblaze*) ARCH=microblaze ;;
+       esac
+}
+
+do_configure() {
+       set_arch
+       oe_runmake allnoconfig ARCH=$ARCH
+}
+
+do_compile () {
+}
+
+do_install() {
+       set_arch
+       oe_runmake headers_install INSTALL_HDR_PATH=${D}${exec_prefix} ARCH=$ARCH
+       # Kernel should not be exporting this header
+       rm -f ${D}${exec_prefix}/include/scsi/scsi.h
+}
+
+BBCLASSEXTEND = "nativesdk"