qemu-config: turn into distcc-config and a package group

* Create a new packagegroup-core-device-devel which pulls in everything
  that qemu-config used to, with the exception of anjuta-remote-run -
  this is unlikely to be widely used
* Move the remainder of qemu-config to distcc-config and allow
  DISTCC_HOSTS to be configured via a variable of the same name
* Use SUMMARY instead of DESCRIPTION for single-line description since
  DESCRIPTION is defaulted from SUMMARY if not set

Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>

diff --git a/meta/recipes-bsp/qemu-config/qemu-config.bb b/meta/recipes-bsp/qemu-config/qemu-config.bb
deleted file mode 100644 (file)
index 3ed07df..0000000
--- a/meta/recipes-bsp/qemu-config/qemu-config.bb
+++ /dev/null
@@ -1,23 +0,0 @@
-DESCRIPTION = "Adds scripts to use distcc on the host system under qemu"
-
-LICENSE = "MIT"
-LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
-                    file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
-
-
-COMPATIBLE_MACHINE = "(qemuarm|qemux86|qemumips|qemuppc)"
-
-PR = "r25"
-
-SRC_URI = "file://distcc.sh"
-
-S = "${WORKDIR}"
-
-do_install() {
-    install -d ${D}${sysconfdir}/profile.d
-    install -m 0755 distcc.sh ${D}${sysconfdir}/profile.d/
-}
-
-RDEPENDS_${PN} = "distcc oprofileui-server bash"
-
-inherit allarch

diff --git a/meta/recipes-devtools/devel-config/distcc-config.bb b/meta/recipes-devtools/devel-config/distcc-config.bb
new file mode 100644 (file)
index 0000000..8deaa66
--- /dev/null
+++ b/meta/recipes-devtools/devel-config/distcc-config.bb
@@ -0,0 +1,25 @@
+SUMMARY = "Sets up distcc for compilation on the target device"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
+                    file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+SRC_URI = "file://distcc.sh"
+
+S = "${WORKDIR}"
+
+# Default to the host machine for a running qemu session
+DISTCC_HOSTS ?= "192.168.7.1"
+
+do_configure() {
+       sed -i "s%@DISTCC_HOSTS@%${DISTCC_HOSTS}%" distcc.sh
+}
+
+do_install() {
+       install -d ${D}${sysconfdir}/profile.d
+       install -m 0755 distcc.sh ${D}${sysconfdir}/profile.d/
+}
+
+RDEPENDS_${PN} = "distcc"
+
+inherit allarch

diff --git a/meta/recipes-bsp/qemu-config/qemu-config/distcc.sh b/meta/recipes-devtools/devel-config/distcc-config/distcc.sh
similarity index 57%
rename from meta/recipes-bsp/qemu-config/qemu-config/distcc.sh
rename to meta/recipes-devtools/devel-config/distcc-config/distcc.sh
index a2b543d6b8295ef79d69bc76203166cfdf024614..b4205931dc155ae8b0cced1918d2777ed7d35952 100644 (file)
--- a/meta/recipes-bsp/qemu-config/qemu-config/distcc.sh
+++ b/meta/recipes-devtools/devel-config/distcc-config/distcc.sh
@@ -1,4 +1,4 @@
-DISTCC_HOSTS="192.168.7.1"
+DISTCC_HOSTS="@DISTCC_HOSTS@"
 #DISTCC_VERBOSE="1"
 
 export DISTCC_HOSTS

diff --git a/meta/recipes-devtools/packagegroups/packagegroup-core-device-devel.bb b/meta/recipes-devtools/packagegroups/packagegroup-core-device-devel.bb
new file mode 100644 (file)
index 0000000..e55eed5
--- /dev/null
+++ b/meta/recipes-devtools/packagegroups/packagegroup-core-device-devel.bb
@@ -0,0 +1,15 @@
+SUMMARY = "Provides a small set of tools for development on the device"
+LICENSE = "MIT"
+
+inherit packagegroup
+
+RPROVIDES_${PN} = "qemu-config"
+RREPLACES_${PN} = "qemu-config"
+
+RDEPENDS_${PN} = "\
+    distcc-config \
+    oprofileui-server \
+    nfs-export-root \
+    bash \
+    "
+