libcap: add new package

version 2.19
as a dependency of nfs-utils

Signed-off-by: Qing He <qing.he@intel.com>

diff --git a/meta/packages/libcap/libcap.inc b/meta/packages/libcap/libcap.inc
new file mode 100644 (file)
index 0000000..7bdecd7
--- /dev/null
+++ b/meta/packages/libcap/libcap.inc
@@ -0,0 +1,35 @@
+DESCRIPTION = "support for getting/setting POSIX.1e capabilities"
+HOMEPAGE = "http://sites.google.com/site/fullycapable/"
+
+# no specific GPL version required
+LICENSE = "BSD | GPL"
+LIC_FILES_CHKSUM = "file://License;md5=731de803c1ccbcb05a9b3523279c8d7f"
+
+DEPENDS = "pam attr perl-native"
+PR = "r0"
+
+SRC_URI = "${KERNELORG_MIRROR}/pub/linux/libs/security/linux-privs/libcap2/${BPN}-${PV}.tar.bz2"
+
+inherit lib_package
+
+do_configure() {
+       # libcap uses := for compilers, fortunately, it gives us a hint
+       # on what should be replaced with ?=
+       sed -e 's,:=,?=,g' -i Make.Rules
+       sed -e 's,BUILD_CFLAGS ?=,BUILD_CFLAGS := $(BUILD_CFLAGS),' -i Make.Rules
+}
+
+EXTRA_OEMAKE = "LIBATTR=yes PAM_CAP=yes INDENT= lib=lib"
+EXTRA_OEMAKE_virtclass-native = "LIBATTR=no PAM_CAP=no INDENT= lib=lib"
+
+do_compile() {
+       oe_runmake
+}
+
+do_install() {
+       oe_runmake install DESTDIR="${D}"
+}
+
+# pam files
+FILES_${PN} += "${libdir}/security/*.so"
+FILES_${PN}-dbg += "${libdir}/security/.debug/*.so"

diff --git a/meta/packages/libcap/libcap_2.19.bb b/meta/packages/libcap/libcap_2.19.bb
new file mode 100644 (file)
index 0000000..474d060
--- /dev/null
+++ b/meta/packages/libcap/libcap_2.19.bb
@@ -0,0 +1,3 @@
+require libcap.inc
+
+PR = "r0"