imx-mkimage: Add recipe for i.MX 8 boot partition packages

Signed-off-by: Tom Hochstein <tom.hochstein@nxp.com>

diff --git a/recipes-bsp/imx-mkimage/imx-mkimage_git.bb b/recipes-bsp/imx-mkimage/imx-mkimage_git.bb
new file mode 100644 (file)
index 0000000..b0a2719
--- /dev/null
+++ b/recipes-bsp/imx-mkimage/imx-mkimage_git.bb
@@ -0,0 +1,35 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2018 NXP
+
+require imx-mkimage_git.inc
+
+DESCRIPTION = "i.MX make image"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"
+SECTION = "BSP"
+
+inherit native deploy
+
+CFLAGS = "-O2 -Wall -std=c99 -static -I ${STAGING_INCDIR} -L ${STAGING_LIBDIR}"
+
+do_compile () {
+    cd ${S}
+    oe_runmake clean
+    oe_runmake bin
+    oe_runmake -C iMX8M -f soc.mak mkimage_imx8
+    oe_runmake -C iMX8QM -f soc.mak imx8qm_dcd.cfg.tmp
+    oe_runmake -C iMX8QX -f soc.mak imx8qx_dcd.cfg.tmp
+}
+
+do_install () {
+    cd ${S}
+    install -d ${D}${bindir}
+    install -m 0755 iMX8M/mkimage_imx8 ${D}${bindir}/mkimage_imx8m
+    install -m 0755 mkimage_imx8 ${D}${bindir}/mkimage_imx8
+}
+
+do_deploy () {
+    install -m 0644 ${S}/iMX8QM/imx8qm_dcd.cfg.tmp ${DEPLOYDIR}
+    install -m 0644 ${S}/iMX8QX/imx8qx_dcd.cfg.tmp ${DEPLOYDIR}
+}
+addtask deploy before do_build after do_install

diff --git a/recipes-bsp/imx-mkimage/imx-mkimage_git.inc b/recipes-bsp/imx-mkimage/imx-mkimage_git.inc
new file mode 100644 (file)
index 0000000..a8cd930
--- /dev/null
+++ b/recipes-bsp/imx-mkimage/imx-mkimage_git.inc
@@ -0,0 +1,11 @@
+# Copyright 2017-2018 NXP
+
+DEPENDS = "zlib-native openssl-native"
+
+SRCBRANCH = "imx_4.9.123_imx8mm_ga"
+SRC_URI = "git://source.codeaurora.org/external/imx/imx-mkimage.git;protocol=https;branch=${SRCBRANCH}"
+SRCREV = "9e289f314eddb9d38cab73780b936acb30bb88b4"
+S = "${WORKDIR}/git"
+
+BOOT_TOOLS = "imx-boot-tools"
+SYSROOT_DIRS += "/boot"