meta-ide-support: A dummy recipe to install everthing for target development

Move the environment-setup script generation into a separate class and adapt
meta-toolchain to use it.

Add a new dummy target, meta-ide-support, to install an appropriately
configured script to TMPDIR and ensure all of the required packages for target
development are available.

Signed-off-by: Joshua Lock <josh@linux.intel.com>

diff --git a/meta/classes/toolchain-scripts.bbclass b/meta/classes/toolchain-scripts.bbclass
new file mode 100644 (file)
index 0000000..8934e0b
--- /dev/null
+++ b/meta/classes/toolchain-scripts.bbclass
@@ -0,0 +1,51 @@
+# This function creates an environment-setup-script for use in a deployable SDK
+toolchain_create_sdk_env_script () {
+       # Create environment setup script
+       script=${SDK_OUTPUT}/${SDKPATH}/environment-setup-${MULTIMACH_TARGET_SYS}
+       rm -f $script
+       touch $script
+       echo 'export PATH=${SDKPATHNATIVE}${bindir_nativesdk}:${SDKPATHNATIVE}${bindir_nativesdk}/${MULTIMACH_TARGET_SYS}:$PATH' >> $script
+       echo 'export PKG_CONFIG_SYSROOT_DIR=${SDKTARGETSYSROOT}' >> $script
+       echo 'export PKG_CONFIG_PATH=${SDKTARGETSYSROOT}${libdir}/pkgconfig' >> $script
+       echo 'export CONFIG_SITE=${SDKPATH}/site-config-${MULTIMACH_TARGET_SYS}' >> $script
+       echo 'export CC=${TARGET_PREFIX}gcc' >> $script
+       echo 'export CXX=${TARGET_PREFIX}g++' >> $script
+       echo 'export CONFIGURE_FLAGS="--target=${TARGET_SYS} --host=${TARGET_SYS} --build=${SDK_ARCH}-linux"' >> $script
+       if [ "${TARGET_OS}" = "darwin8" ]; then
+               echo 'export TARGET_CFLAGS="-I${SDKTARGETSYSROOT}${includedir}"' >> $script
+               echo 'export TARGET_LDFLAGS="-L${SDKTARGETSYSROOT}${libdir}"' >> $script
+               # Workaround darwin toolchain sysroot path problems
+               cd ${SDK_OUTPUT}${SDKTARGETSYSROOT}/usr
+               ln -s /usr/local local
+       fi
+       echo 'export CFLAGS="${TARGET_CC_ARCH}"' >> $script
+       echo 'export CXXFLAGS="${TARGET_CC_ARCH}"' >> $script
+       echo "alias opkg='LD_LIBRARY_PATH=${SDKPATHNATIVE}${libdir_nativesdk} ${SDKPATHNATIVE}${bindir_nativesdk}/opkg-cl -f ${SDKPATHNATIVE}/${sysconfdir}/opkg-sdk.conf -o ${SDKPATHNATIVE}'" >> $script
+       echo "alias opkg-target='LD_LIBRARY_PATH=${SDKPATHNATIVE}${libdir_nativesdk} ${SDKPATHNATIVE}${bindir_nativesdk}/opkg-cl -f ${SDKTARGETSYSROOT}${sysconfdir}/opkg.conf -o ${SDKTARGETSYSROOT}'" >> $script
+}
+
+# This function creates an environment-setup-script in the TMPDIR which enables a Poky IDE to integrate with the
+# build tree
+toolchain_create_tree_env_script () {
+       script=${TMPDIR}/environment-setup-${MULTIMACH_TARGET_SYS}
+       rm -f $script
+       touch $script
+       echo 'export PATH=${PATH}' >> $script
+       echo 'export PKG_CONFIG_SYSROOT_DIR=${STAGING_DIR}/${TARGET_SYS}' >> $script
+       echo 'export PKG_CONFIG_PATH=${STAGING_DIR}/${TARGET_SYS}${libdir}/pkgconfig' >> $script
+
+       echo 'export CONFIG_SITE="${@siteinfo_get_files(d)}"' >> $script
+
+       echo 'export CC=${TARGET_PREFIX}gcc' >> $script
+       echo 'export CXX=${TARGET_PREFIX}g++' >> $script
+       echo 'export CONFIGURE_FLAGS="--target=${TARGET_SYS} --host=${TARGET_SYS} --build=${BUILD_SYS}"' >> $script
+       if [ "${TARGET_OS}" = "darwin8" ]; then
+               echo 'export TARGET_CFLAGS="-I${STAGING_DIR}${TARGET_SYS}${includedir}"' >> $script
+               echo 'export TARGET_LDFLAGS="-L${STAGING_DIR}${TARGET_SYS}${libdir}"' >> $script
+               # Workaround darwin toolchain sysroot path problems
+               cd ${SDK_OUTPUT}${SDKTARGETSYSROOT}/usr
+               ln -s /usr/local local
+       fi
+       echo 'export CFLAGS="${TARGET_CC_ARCH}"' >> $script
+       echo 'export CXXFLAGS="${TARGET_CC_ARCH}"' >> $script
+}

diff --git a/meta/packages/meta/meta-ide-support.bb b/meta/packages/meta/meta-ide-support.bb
new file mode 100644 (file)
index 0000000..0d564ba
--- /dev/null
+++ b/meta/packages/meta/meta-ide-support.bb
@@ -0,0 +1,15 @@
+DESCRIPTION = "Meta package for ensuring the build directory contains all appropriate toolchain packages for using an IDE"
+LICENSE = "MIT"
+DEPENDS = "virtual/libc"
+RDEPENDS = "task-sdk-host"
+PR = "r0"
+
+inherit meta toolchain-scripts
+
+do_populate_ide_support () {
+  toolchain_create_tree_env_script
+}
+
+do_populate_ide_support[nostamp] = "1"
+do_populate_ide_support[recrdeptask] = "do_package_write"
+addtask populate_ide_support before do_build after do_install

diff --git a/meta/packages/meta/meta-toolchain.bb b/meta/packages/meta/meta-toolchain.bb
index a53569b55b625e9a67fa985dbbcf2fcd849cf771..585adb4e13e47f2fda84e437397a092ff426f530 100644 (file)
--- a/meta/packages/meta/meta-toolchain.bb
+++ b/meta/packages/meta/meta-toolchain.bb
@@ -2,7 +2,7 @@ DESCRIPTION = "Meta package for building a installable toolchain"
 LICENSE = "MIT"
 DEPENDS = "opkg-native opkg-utils-native virtual/fakeroot-native sed-native"
 
-inherit meta
+inherit meta toolchain-scripts
 
 SDK_DIR = "${WORKDIR}/sdk"
 SDK_OUTPUT = "${SDK_DIR}/image"
@@ -79,27 +79,7 @@ do_populate_sdk() {
                cat $sitefile >> $siteconfig
        done
 
-       # Create environment setup script
-       script=${SDK_OUTPUT}/${SDKPATH}/environment-setup-${MULTIMACH_TARGET_SYS}
-       touch $script
-       echo 'export PATH=${SDKPATHNATIVE}${bindir_nativesdk}:${SDKPATHNATIVE}${bindir_nativesdk}/${MULTIMACH_TARGET_SYS}:$PATH' >> $script
-       echo 'export PKG_CONFIG_SYSROOT_DIR=${SDKTARGETSYSROOT}' >> $script
-       echo 'export PKG_CONFIG_PATH=${SDKTARGETSYSROOT}${libdir}/pkgconfig' >> $script
-       echo 'export CONFIG_SITE=${SDKPATH}/site-config-${MULTIMACH_TARGET_SYS}' >> $script
-       echo 'export CC=${TARGET_PREFIX}gcc' >> $script
-       echo 'export CXX=${TARGET_PREFIX}g++' >> $script
-       echo 'export CONFIGURE_FLAGS="--target=${TARGET_SYS} --host=${TARGET_SYS} --build=${SDK_ARCH}-linux"' >> $script
-       if [ "${TARGET_OS}" = "darwin8" ]; then
-               echo 'export TARGET_CFLAGS="-I${SDKTARGETSYSROOT}${includedir}"' >> $script
-               echo 'export TARGET_LDFLAGS="-L${SDKTARGETSYSROOT}${libdir}"' >> $script
-               # Workaround darwin toolchain sysroot path problems
-               cd ${SDK_OUTPUT}${SDKTARGETSYSROOT}/usr
-               ln -s /usr/local local
-       fi
-       echo 'export CFLAGS="${TARGET_CC_ARCH}"' >> $script
-       echo 'export CXXFLAGS="${TARGET_CC_ARCH}"' >> $script
-       echo "alias opkg='LD_LIBRARY_PATH=${SDKPATHNATIVE}${libdir_nativesdk} ${SDKPATHNATIVE}${bindir_nativesdk}/opkg-cl -f ${SDKPATHNATIVE}/${sysconfdir}/opkg-sdk.conf -o ${SDKPATHNATIVE}'" >> $script
-       echo "alias opkg-target='LD_LIBRARY_PATH=${SDKPATHNATIVE}${libdir_nativesdk} ${SDKPATHNATIVE}${bindir_nativesdk}/opkg-cl -f ${SDKTARGETSYSROOT}${sysconfdir}/opkg.conf -o ${SDKTARGETSYSROOT}'" >> $script
+       toolchain_create_sdk_env_script
 
        # Add version information
        versionfile=${SDK_OUTPUT}/${SDKPATH}/version-${MULTIMACH_TARGET_SYS}