Add depicture machine with patches from SimTec

diff --git a/meta/conf/machine/depicture.conf b/meta/conf/machine/depicture.conf
new file mode 100644 (file)
index 0000000..333af4f
--- /dev/null
+++ b/meta/conf/machine/depicture.conf
@@ -0,0 +1,32 @@
+#@TYPE: Machine
+#@NAME: Simtec BBD20EUROU + IM2440D20 (Combination known as: Depicture)
+#@DESCRIPTION: Machine configuration for running an ARM 920t in the BBD20EUROU board.
+
+TARGET_ARCH = "arm"
+PACKAGE_EXTRA_ARCHS = "armv4 armv4t"
+
+require conf/machine/include/qemu.inc
+require conf/machine/include/tune-arm920t.inc
+
+KERNEL_IMAGETYPE = "zImage"
+
+SERIAL_CONSOLE = "115200 ttySAC0"
+
+PREFERRED_PROVIDER_virtual/kernel = "linux-simtec"
+PREFERRED_PROVIDER_virtual/xserver = "xserver-kdrive-fbdev"
+
+MACHINE_FEATURES = "kernel26 alsa usbhost"
+XSERVER = "xserver-kdrive-fbdev"
+
+SERIAL_CONSOLE = "115200 ttySAC0"
+
+# used by some images
+ROOT_FLASH_SIZE = "28"
+
+# Ensure the JFFS2 has summary nodes...
+IMAGE_FSTYPES += " jffs2"
+EXTRA_IMAGECMD_jffs2 = "--little-endian --eraseblock=0x20000 --pagesize=0x800 \
+  --no-cleanmarkers --pad -n -x lzo ; sumtool --eraseblock=0x20000 --no-cleanmarkers \
+  --littleendian --pad \
+  -i ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 \
+  -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2.summary"

diff --git a/meta/packages/linux/linux-simtec-2.6.26-simtec1/depicture-defconfig-append b/meta/packages/linux/linux-simtec-2.6.26-simtec1/depicture-defconfig-append
new file mode 100644 (file)
index 0000000..fc1af85
--- /dev/null
+++ b/meta/packages/linux/linux-simtec-2.6.26-simtec1/depicture-defconfig-append
@@ -0,0 +1,18 @@
+# The Depicture needs the S3C24xx's Framebuffer and LCD stuff
+CONFIG_FB_S3C2410=y
+CONFIG_LCD_CLASS_DEVICE=y
+CONFIG_BACKLIGHT_CLASS_DEVICE=y
+CONFIG_BACKLIGHT_S3C2410=y
+CONFIG_LCD_PLATFORM=y
+CONFIG_BACKLIGHT_PWM=y
+CONFIG_SIMTEC_LCD=y
+# And also the touchscreen interface
+CONFIG_TOUCHSCREEN_S3C2410=y
+CONFIG_INPUT_EVDEV=y
+CONFIG_SENSORS_S3C_ADC=y
+# And the MMC makes sense to compile in.
+CONFIG_MMC=y
+CONFIG_MMC_BLOCK=y
+CONFIG_MMC_S3C=y
+# IPv6 is needed for the X server
+CONFIG_IPV6=y

diff --git a/meta/packages/linux/linux-simtec.inc b/meta/packages/linux/linux-simtec.inc
new file mode 100644 (file)
index 0000000..b9503ce
--- /dev/null
+++ b/meta/packages/linux/linux-simtec.inc
@@ -0,0 +1,22 @@
+require linux.inc
+
+do_prepdefconfig() {
+       cp ${S}/arch/arm/configs/s3c24xx_simtec_defconfig ${WORKDIR}/defconfig
+       if test -e ${WORKDIR}/${MACHINE}-defconfig-append; then
+          cat ${WORKDIR}/${MACHINE}-defconfig-append >> ${WORKDIR}/defconfig
+       fi
+}
+
+addtask prepdefconfig before do_configure after do_patch
+
+do_deploy() {
+       install -d ${DEPLOY_DIR_IMAGE}
+       install -m 0644 arch/${ARCH}/boot/${KERNEL_IMAGETYPE} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${PV}-${MACHINE}-${DATETIME}.bin
+       cd ${DEPLOY_DIR_IMAGE}
+       ln -sf ${KERNEL_IMAGETYPE}-${PV}-${MACHINE}-${DATETIME}.bin ${KERNEL_IMAGETYPE}-${MACHINE}.bin
+       tar -cvzf ${DEPLOY_DIR_IMAGE}/modules-${KERNEL_RELEASE}-${MACHINE}.tgz -C ${D} lib      
+}
+
+do_deploy[dirs] = "${S}"
+
+addtask deploy before do_populate_staging after do_install

diff --git a/meta/packages/linux/linux-simtec_2.6.26-simtec1.bb b/meta/packages/linux/linux-simtec_2.6.26-simtec1.bb
new file mode 100644 (file)
index 0000000..9eb2c88
--- /dev/null
+++ b/meta/packages/linux/linux-simtec_2.6.26-simtec1.bb
@@ -0,0 +1,15 @@
+require linux-simtec.inc
+
+PR = "r1"
+
+PROVIDES += "virtual/kernel"
+
+DEFAULT_PREFERENCE = "-1"
+DEFAULT_PREFERENCE_depicture = "1"
+
+SRC_URI = "${KERNELORG_MIRROR}pub/linux/kernel/v2.6/linux-2.6.26.tar.bz2 \
+           http://www.simtec.co.uk/products/SWLINUX/files/patch-2.6.26-simtec1.bz2;patch=1 \
+          file://${MACHINE}-defconfig-append \
+          "
+
+S = "${WORKDIR}/linux-2.6.26"