From: Ting Liu <b28495@freescale.com>
Date: Fri, 14 Dec 2012 16:51:58 +0000 (+0000)
Subject: fmc_git: add recipe
X-Git-Tag: 2.1~534^2~321
X-Git-Url: https://code.ossystems.io/gitweb?a=commitdiff_plain;h=3ed0eeaacd3db85324e8e463432062defa664009;p=meta-freescale.git

fmc_git: add recipe

Signed-off-by: Ting Liu <b28495@freescale.com>
---

diff --git a/meta-fsl-ppc/recipes-ucode/fmc/fmc_git.bb b/meta-fsl-ppc/recipes-ucode/fmc/fmc_git.bb
new file mode 100644
index 00000000..c5a3bc16
--- /dev/null
+++ b/meta-fsl-ppc/recipes-ucode/fmc/fmc_git.bb
@@ -0,0 +1,45 @@
+DESCRIPTION = "Frame Manager Configuration tool"
+SECTION = "fmc"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=a504ab5a8ff235e67c7301214749346c"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/fmc.git"
+SRCREV = "274ff60dd9d7dd9f881deeb86c2c4b8a342e55d1"
+
+DEPENDS = "libxml2 fmlib tclap"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'FMD_USPACE_HEADER_PATH="${STAGING_INCDIR}/fmd" \
+    FMD_USPACE_LIB_PATH="${STAGING_LIBDIR}" LIBXML2_HEADER_PATH="${STAGING_INCDIR}/libxml2" \
+    TCLAP_HEADER_PATH="${STAGING_INCDIR}" '
+EXTRA_OEMAKE_virtclass-native = 'FMCHOSTMODE=1 FMD_USPACE_HEADER_PATH="${STAGING_INCDIR}/fmd" \
+    FMD_USPACE_LIB_PATH="${STAGING_LIBDIR}" LIBXML2_HEADER_PATH="${STAGING_INCDIR}/libxml2" \
+    TCLAP_HEADER_PATH="${STAGING_INCDIR}" '
+
+do_compile () {
+    if [ "b4860qds" = "${MACHINE}" ] || [ "b4420qds" = "${MACHINE}" ];then
+        EXTRA_OEMAKE_PLATFORM="b4860qds"
+    elif [ "t4240qds" = "${MACHINE}" ] || [ "t4160qds" = "${MACHINE}" ];then
+        EXTRA_OEMAKE_PLATFORM="t4240qds"
+    elif [ "p1023rds" = "${MACHINE}" ];then
+        EXTRA_OEMAKE_PLATFORM="p1023rds"
+    else
+        EXTRA_OEMAKE_PLATFORM=""
+    fi
+    oe_runmake MACHINE=${EXTRA_OEMAKE_PLATFORM} -C source
+}
+
+do_install () {
+    install -d ${D}/${bindir}
+    install -m 755 ${S}/source/fmc ${D}/${bindir}/fmc
+
+    install -d ${D}/etc/fmc/config
+    install -m 644 ${S}/etc/fmc/config/hxs_pdl_v3.xml ${D}/etc/fmc/config
+}
+
+PARALLEL_MAKE = ""
+
+BBCLASSEXTEND = "native"