From: Zhenhua Luo <zhenhua.luo@freescale.com>
Date: Thu, 27 Jun 2013 09:25:12 +0000 (+0000)
Subject: qoriq-debug: add recipe
X-Git-Tag: 2.1~534^2~267
X-Git-Url: https://code.ossystems.io/gitweb?a=commitdiff_plain;h=75f3a64365d60c2357e4816a9fac363435ef11e4;p=meta-freescale.git

qoriq-debug: add recipe

QorIQ Debug File System Module

Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
---

diff --git a/meta-fsl-ppc/recipes-kernel/qoriq-debug/qoriq-debug_git.bb b/meta-fsl-ppc/recipes-kernel/qoriq-debug/qoriq-debug_git.bb
new file mode 100644
index 00000000..a8d2e963
--- /dev/null
+++ b/meta-fsl-ppc/recipes-kernel/qoriq-debug/qoriq-debug_git.bb
@@ -0,0 +1,34 @@
+DESCRIPTION = "QorIQ Debug File System Module"
+SECTION = "qoriq-debug"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=e29234dd5d40dc352cc60cc0c93437ba"
+
+inherit module autotools
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/qoriq-debug.git"
+SRCREV = "08de2902af9a79ba9e436a284b8d7754b351f608"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OECONF += "--with-linux=${STAGING_KERNEL_DIR}"
+EXTRA_OEMAKE += 'SYSROOT="${D}"'
+
+python () {
+	ma = d.getVar("DISTRO_FEATURES", True)
+	arch = d.getVar("OVERRIDES", True)
+
+	# the : after the arch is to skip the message on 64b
+	if not "multiarch" in ma and ("e5500:" in arch or "e6500:" in arch):
+		raise bb.parse.SkipPackage("Building the kernel for this arch requires multiarch to be in DISTRO_FEATURES")
+
+	promote_kernel = d.getVar('BUILD_64BIT_KERNEL')
+
+	if promote_kernel == "1":
+		d.setVar('KERNEL_CC_append', ' -m64')
+		d.setVar('KERNEL_LD_append', ' -melf64ppc')
+
+	error_qa = d.getVar('ERROR_QA', True)
+	if 'arch' in error_qa:
+		d.setVar('ERROR_QA', error_qa.replace(' arch', ''))
+}
+