From: Joris Offouga <offougajoris@gmail.com>
Date: Mon, 15 Oct 2018 15:03:36 +0000 (+0200)
Subject: u-boot-qoriq: Add recipe fw-utils
X-Git-Url: https://code.ossystems.io/gitweb?a=commitdiff_plain;h=bb4dcaa73c446fe77af8cf7782dafe9ccd7b58be;p=meta-freescale.git

u-boot-qoriq: Add recipe fw-utils

Initial support for fw utils for qoriq

Signed-off-by: Joris Offouga <offougajoris@gmail.com>
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---

diff --git a/recipes-bsp/u-boot/u-boot-qoriq-fw-utils_2018.03.bb b/recipes-bsp/u-boot/u-boot-qoriq-fw-utils_2018.03.bb
new file mode 100644
index 00000000..ae47cb0d
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-qoriq-fw-utils_2018.03.bb
@@ -0,0 +1,45 @@
+require u-boot-qoriq-common_${PV}.inc
+
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+DEPENDS = "mtd-utils"
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'ARCH=${TARGET_ARCH} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+    oe_runmake ${UBOOT_MACHINE}
+    oe_runmake envtools
+}
+
+do_install () {
+    install -d ${D}${base_sbindir}
+    install -d ${D}${sysconfdir}
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+
+    if [ -e ${WORKDIR}/fw_env.config ]; then
+        install -m 0644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config
+    else
+        install -m 0644 ${S}/tools/env/fw_env.config ${D}${sysconfdir}/fw_env.config
+    fi
+}
+
+do_install_class-cross () {
+    install -d ${D}${bindir_cross}
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_PREPROCESS_FUNCS_class-cross = "uboot_fw_utils_cross"
+uboot_fw_utils_cross() {
+    sysroot_stage_dir ${D}${bindir_cross} ${SYSROOT_DESTDIR}${bindir_cross}
+}
+
+PROVIDES += "u-boot-fw-utils"
+RPROVIDES_${PN} += "u-boot-fw-utils"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"