From: Daniel Klauer <daniel.klauer@gin.de>
Date: Thu, 1 Aug 2019 09:06:56 +0000 (+0200)
Subject: Split fiptool build into separate recipe
X-Git-Url: https://code.ossystems.io/gitweb?a=commitdiff_plain;h=c090df937b5f9e5487c045d1a6c958ef65abd87d;p=meta-freescale.git

Split fiptool build into separate recipe

Previously, ddr-phy built native fiptool during its own build process,
but without using Yocto's native toolchain settings. This results in
unexpected host dependencies. For example, fiptool depends on openssl,
which may or may not be installed on the host.

So now fiptool is built in a separate recipe (atf-tools-native) which can
easily depend on openssl.

Signed-off-by: Daniel Klauer <daniel.klauer@gin.de>
---

diff --git a/recipes-bsp/atf/atf-tools_git.bb b/recipes-bsp/atf/atf-tools_git.bb
new file mode 100644
index 00000000..a5998fe2
--- /dev/null
+++ b/recipes-bsp/atf/atf-tools_git.bb
@@ -0,0 +1,19 @@
+SUMMARY = "Tools for ARM Trusted Firmware, e.g. FIP image creation tool"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://license.rst;md5=e927e02bca647e14efd87e9e914b2443"
+
+SRC_URI = "git://source.codeaurora.org/external/qoriq/qoriq-components/atf;nobranch=1"
+SRCREV = "17f94e4315e81e3d1b22d863d9614d724e8273dc"
+
+S = "${WORKDIR}/git"
+
+DEPENDS += "openssl"
+
+EXTRA_OEMAKE = "fiptool V=1 HOSTCC='${CC} ${CPPFLAGS} ${CFLAGS} ${LDFLAGS}'"
+
+do_install () {
+    install -m 0755 -d ${D}/${bindir}
+    install -m 0755 ${S}/tools/fiptool/fiptool ${D}/${bindir}/
+}
+
+BBCLASSEXTEND = "native"
diff --git a/recipes-bsp/ddr-phy/ddr-phy_git.bb b/recipes-bsp/ddr-phy/ddr-phy_git.bb
index 98a9b029..d98d102f 100644
--- a/recipes-bsp/ddr-phy/ddr-phy_git.bb
+++ b/recipes-bsp/ddr-phy/ddr-phy_git.bb
@@ -4,19 +4,18 @@ LIC_FILES_CHKSUM = "file://NXP-Binary-EULA.txt;md5=89cc852481956e861228286ac7430
 
 inherit deploy fsl-eula-unpack
 
-SRC_URI = "git://github.com/nxp/ddr-phy-binary.git;fsl-eula=true;nobranch=1 \
-    git://source.codeaurora.org/external/qoriq/qoriq-components/atf;nobranch=1;destsuffix=git/atf;name=atf"
+SRC_URI = "git://github.com/nxp/ddr-phy-binary.git;fsl-eula=true;nobranch=1"
 SRCREV = "14d03e6e748ed5ebb9440f264bb374f1280b061c"
-SRCREV_atf = "17f94e4315e81e3d1b22d863d9614d724e8273dc"
 
 S = "${WORKDIR}/git"
 
 REGLEX_lx2160a = "lx2160a"
 
-do_install () {
-    oe_runmake -C ${S}/atf fiptool
+DEPENDS += "atf-tools-native"
+
+do_compile() {
     cd ${S}/${REGLEX}
-    ${S}/atf/tools/fiptool/fiptool create --ddr-immem-udimm-1d ddr4_pmu_train_imem.bin \
+    fiptool create --ddr-immem-udimm-1d ddr4_pmu_train_imem.bin \
     --ddr-immem-udimm-2d ddr4_2d_pmu_train_imem.bin \
     --ddr-dmmem-udimm-1d ddr4_pmu_train_dmem.bin \
     --ddr-dmmem-udimm-2d ddr4_2d_pmu_train_dmem.bin \
@@ -25,6 +24,9 @@ do_install () {
     --ddr-dmmem-rdimm-1d ddr4_rdimm_pmu_train_dmem.bin \
     --ddr-dmmem-rdimm-2d ddr4_rdimm2d_pmu_train_dmem.bin \
     fip_ddr_all.bin
+}
+
+do_install () {
     install -d ${D}/boot
     install -m 755 ${S}/${REGLEX}/*.bin ${D}/boot
 }